Конспект лекций по дисциплине «Высокоуровневые методы информатики и программирования» для студентов специальности 080801 «Прикладная информатика в экономике»

Вид материала

Содержание

A.Value :=n
Unit Circul
MyObject[k+2,s] :=1
Пример 3.35.
Unit MasByte
Function Delete(Ind:byte):byte
Индексируемые свойства (свойства со спецификацией index).
Type CMas=class

Подобный материал:

1 ... 17 18 19 20 21 22 23 24 25

Свойства

Свойство - это средство Pascal Delphi, позволяющее определять интерфейс доступа к полям класса.

В Delphi различают:

простые или скалярные свойства;
свойства-массивы;
индексируемые свойства или свойства со спецификацией index;
процедурные свойства.

Простые свойства. Описание простых свойств выполняется следующим образом (квадратные скобки в данном случае указывают, что соответствующая спецификация может быть опущена):

property <имя свойства>:<тип>

[read <метод чтения или имя поля>]

[write <метод записи или имя поля>]

[stored <метод или булевское значение>]

[default <константа>];

Спецификации, начинающиеся служебными словами read и write, определяют соответственно методы, которые должны быть использованы для чтения и записи свойства. Если метод чтения не определен, то свойство не доступно для чтения. Если метод записи не определен, то свойство не доступно для записи.

Вместо метода чтения или записи возможно указание имени поля. Это означает, что данному свойству соответствует поле в описании класса, куда осуществляется непосредственная запись или откуда выполняется непосредственное чтение (без использования методов).

Остальные спецификации названные спецификациями сохранения используются только для свойств, определяемых в секции published, т.е. используемых для «опубликованных» компонент. Булевское значение после stored (вместо которого может быть указан метод, возвращающий булевское значение) определяет, должно ли сохраняться данное свойство компонента при сохранении формы (true - должно, false - не должно) в файле с расширением .dfm. Последний спецификатор default определяет стандартное значение свойства, при совпадении значения поля с которым свойство не сохраняется.

Например:

private FValue:integer;

procedure SetValue(AValue:integer);

function StoreValue:boolean;

published

property Value:integer read FValue write SetValue

stored StoreValue default 10; . . .

Данное описание определяет свойство для внутреннего поля FValue некоторого класса. Чтение свойства выполняется напрямую из поля. Для записи в поле используется специальный метод SetValue. Сохранение в форме выполняется, если метод StoreValue возвращает true и значение отлично от 10.

Примечание. Принято называть поле класса, для которого определяется свойство, тем же именем, что и свойство, но с префиксом «F», а соответствующие параметры методов ввода и вывода с префиксом «A». Аналогично, имя метода чтения свойства желательно начинать с префикса «Get», метода записи - с «Set».

При необходимости в производном классе свойство можно переопределить, изменив доступность и/или спецификации. При этом можно указывать только изменяемые спецификации: остальные - наследуются.

В программе свойства используются как обычные поля, например:

^ A.Value :=n; или k:=A.Value;

соответственно при этом будут выполняться следующие операции:

A.SetValue(n); и k:=A.FValue;

Простые свойства целесообразно использовать:

для ограничения доступа к полю (например, доступ только для чтения);
при необходимости обеспечить при записи или чтении выполнение некоторых дополнительных действий (например, при записи в поле необходимо еще и фиксировать факт изменение значения).

Пример 3.34. Использование простых свойств (графический редактор «Окружности» - вариант 2)

Продемонстрируем особенности программирования с использованием свойств на примере 5.1. В нем мы разрабатывали приложение, позволяющее рисовать на специальном поле окна приложения окружности.

Определим в классе два свойства Color и Radius. Изменение значений этих свойств свяжем с перерисовкой окружности. На рис. 5.9 представлена диаграмма класса TMyCircul для этого варианта.

Рис. 3.69. Диаграмма класса TMyCircul

Довавим еще одно изменение: поместим вызов процедуры рисования Draw в конструктор, так как конструирование объекта обычно связано с его рисованием. Ниже приводится текст модуля Circul.

^ Unit Circul;

Interface

Uses extctrls,Graphics;

Type TMyCircul=class

private x,y,FRadius:Word; FColor:TColor; Image:TImage;

Procedure Clear;

Procedure Draw;

Procedure SetSize(ARadius:Word);

Procedure SetColor(AColor:TColor);

public

Constructor Create(aImage:TImage;ax,ay,ARadius:Word;

AColor:TColor);

property Radius:Word write SetSize;

property Color:TColor write SetColor;

end;

Implementation

Constructor TMyCircul.Create;

Begin inherited Create;

Image:=aImage; x:=ax; y:=ay;

FRadius:=ARadius; FColor:=AColor;

Draw;

End;

Procedure TMyCircul.Draw;

Begin Image.Canvas.Pen.Color:=FColor;

Image.Canvas.Ellipse(x-FRadius, y-FRadius,

x+FRadius, y+FRadius);

End;

Procedure TMyCircul.Clear;

Var TempColor:TColor;

Begin TempColor:=FColor;

FColor:=Image.Canvas.Brush.Color;

Draw;

FColor:=TempColor;

End;

Procedure TMyCircul.SetSize;

Begin Clear; FRadius:=ARadius; Draw; end;

Procedure TMyCircul.SetColor;

Begin Clear; FColor:=AColor; Draw; end;

End.

При такой реализации класса вызов процедуры изменения размера и цвета рисунка будут программироваться как переназначение соответствующего свойства:

C.Radius:=strtoint(rEdit.Text); или C.Color:=ColorDialog.Color;

Примечание. Именно такой способ программирования лежит в основе всех стандартных компонент Delphi. Так, например, изменение свойства Visible, определенного для всех визуальных компонент, сопровождается в зависимости от ситуации появлением или исчезновением соответствующего компонента.

Анализ приведенного текста программы показывает, что использование простых свойств позволяет сократить количество компонентов класса, описанных в интерфейсной части (секция public), т.е. увеличивает степень инкапсуляции объектов.

Свойства-массивы. Описание свойств-массивов осуществляется следующим образом (квадратные скобки означают, что соответствующая спецификация может быть не указана):

property <имя> <список индексных параметров>:<тип>

[read <метод чтения>] [write <метод записи>] [default];

Список индексных параметров заключается в квадратные скобки. Это делает свойства-массивы внешне похожими на обычные массивы. Однако индексные параметры не являются индексами в привычном понимании этого термина. Значения индексных параметров, указанные при обращении к свойствам, передаются в методы чтения и записи в качестве обычных параметров. Соответственно тип индексных параметров может быть не только порядковым, но и вещественным или структурным.

В спецификациях доступа должны указываться методы, количество, тип и порядок следования параметров которых должны соответствовать списку индексных параметров. Параметр-значение в методе записи при этом указывается в конце списка.

Спецификация default используется для указания того, что из всех свойств объекта именно данное принимается по умолчанию (при обращении к объекту может быть опущено).

Например:

private function GetValMas(I:word;F:double):word;

procedure SetValMas(I:word;F:double;AElement:word);

public prorerty ValMas[I:word, F:double]:word

read GetValMas write SetValMas; default;

Приведенное описание означает, что для объекта определено некоторое свойство-массив, чтение и запись элементов которого выполняются специальными методами. Причем при обращении к данному свойству имя свойства можно не указывать, так как оно объявлено используемым по умолчанию например:

^ MyObject[k+2,s] :=1; эквивалентно MyObject.ValMas[k+2,s]:=1;

Свойства-массивы можно использовать для работы со сложными структурами, состоящими из однотипных элементов, например, динамическими массивами (так обычно называют массивы, размещенные в динамической памяти).

^ Пример 3.35. Использование свойств-массивов (класс Динамический массив)

Пусть требуется разработать класс для реализации динамического массива с произвольным количеством элементов-байт. Максимальный размер массива необходимо определяться при его создании. В процессе работы должен отслеживаться реальный размер массива.

Предусмотреть возможность выполнения следующих операций:

ввод массива из элемента TSringGrid и вывод в такой же элемент;
модификацию указанного элемента;
вставку элемента на указанное место;
удаление элемента с заданным индексом.

Кроме того, предусмотреть возможность обращения к любому элементу массива по индексу и обеспечить контроль правильности выполнения указанных операций.

^ Unit MasByte;

Interface

Uses SysUtils,Dialogs, Grids;

Type

TMas=array[1..255] of byte;

TMasByte = class(TObject) {класс «Динамический массив»}

private

ptr_an: ^TMas; {указатель на массив}

len:byte; {максимальная длина массива}

Procedure SetEl(Ind:byte;m:byte); {процедура записи элемента}

Function GetEl(Ind:byte):byte; {функция чтения элемента}

public

n:Byte; {реальный размер массива}

Сonstructor Create(an:byte);

Destructor Destroy;override;

Property Mas[Ind: byte]:byte read GetEl write SetEl;default;

Procedure Modify(Ind:byte;Value:byte); {модификация элемента}

Procedure Insert(Ind:byte;Value:byte); {вставка элемента}

^ Function Delete(Ind:byte):byte; {удаление элемента}

Function InputMas(Grid:TStringGrid;I,J:integer):boolean; {ввод}

Procedure OutputMas(Grid:TStringGrid;I,J:integer); {вывод}

end;

Implementation

Constructor TMasByte.Create;

Begin

inherited Create;

GetMem(ptr_an,an); len:=an; { n:=0; указывать не надо}

End;

Destructor TMasByte.Destroy;

Begin

FreeMem(ptr_an);

inherited Destroy;

End;

Procedure TMasByte.SetEl(Ind:byte;m:byte);

Begin

if Ind<=len then

if Ind<=n then ptr_an^[Ind]:=m

else

MessageDlg('В массиве нет'+inttostr(Ind)+

'-го элемента.',mtError,[mbOk],0)

else

MessageDlg('В массиве можно разместить только'+

inttostr(Len)+' элементов.',mtError,[mbOk],0);

End;

Function TMasByte.GetEl(Ind:byte):byte;

Begin

If Ind<=n then Result:=ptr_an^[Ind]

else

MessageDlg('В массиве нет '+inttostr(Ind)+

'-го элемента.',mtError,[mbOk],0);

End;

Function TMasByte.InputMas(Grid:TStringGrid;I,J:integer):boolean;

Var k:byte; x,er_code:integer;

Begin

with Grid do

begin

k:=0;

Result:=true;

while (Cells[k+I,J]<>'')and Result do

begin

Val(Cells[k+I,J],x,er_code);

if er_code=0 then

if x<=255 then Insert(k+1,x)

else

begin

MessageDlg('Значение не может превышать 255.',

mtError,[mbOk],0);

Result:=false;

Exit;

end

else

begin

MessageDlg('В строке обнаружены недопустимые

символы.',mtError,[mbOk],0);

Result:=false;

Exit;

end;

k:=k+1;

end;

OutputMas(Grid,I,J);

end;

End;

Procedure TMasByte.OutputMas(Grid:TStringGrid;I,J:integer);

Var k:byte;

Begin

with Grid do

begin

if n+I>ColCount then ColCount:=n+I;

for k:=0 to ColCount-1 do

if k

else Cells[I+k,J]:='';

end;

End;

Procedure TMasByte.Modify;

Begin Mas[Ind]:=Value; End;

Procedure TMasByte.Insert;

Var i:integer;

Begin

n:=n+1; for i:=n-1 downto Ind do Mas[i+1]:=Mas[i];

Mas[Ind]:=Value;

End;

Function TMasByte.Delete;

Var i:integer;

Begin

Result:=Mas[Ind];

for i:=Ind+1 to n do Mas[i-1]:=Mas[i]; n:=n-1;

End;

End.

Для работы с динамическим массивом необходимо создать соответствующий объект:

A:=TMasByte.Create(k);

после чего для обращения к элементам достаточно указать имя объекта и индекс, начиная с 1:

A[6]:=7;

Приведенный пример демонстрирует, что свойства-массивы, создают иллюзию работы с массивом, позволяя не вникать в особенности реализации конкретной структуры.

^ Индексируемые свойства (свойства со спецификацией index). Описание индексируемых свойств выполняется следующим образом:

property <имя> : <тип> index <константа>

read <метод чтения> write <метод записи>;

где <константа> - целое число типа ShortInt.

Обычно одновременно описывается несколько свойств с различными значениями индексов, но одними и теми же методами чтения/записи. Методы чтения/записи должны содержать параметр, через который метод получит конкретное значение индекса. Причем в методе чтения данный параметр должен быть последним, а в методе записи - предпоследним, так как последним в нем описывается параметр, определяющий новое значение свойства. Значение параметра-индекса затем используется для определения поля, соответствующего свойству. Таким полем может являться, например, элемент массива.

Например:

^ Type CMas=class

private

FMasEl:array[1:3] of word; {поле-массив}

function GetEl(Ind:byte):word; {метод чтения}

procedure SetEl(Ind:byte;AElement); {метод записи}

public

property Element1:word index 1 read GetEl write SetEl;

property Element2:word index 2 read GetEl write SetEl;

property Element3:word index 3 read GetEl write SetEl;

end;

Function CMas. GetEl;

Begin Result:=FMasEl[Ind]; End;

Procedure CMas. SetEl;

Begin FMasEl[Ind]:=AElement; End;

Свойства в этом случае использованы для обращения к элементам массива.

Процедурные свойства описывают интерфейс к полям, содержащим указатели на методы. Они в основном применяются для подключения методов обработки событий и будут рассмотрены в разделе 5.6.

Blog

Конспект лекций по дисциплине «Высокоуровневые методы информатики и программирования» для студентов специальности 080801 «Прикладная информатика в экономике»

Содержание

Свойства