Е. К. Пугачев Объектно-ориентированное программирование Под общей редакцией Ивановой Г. С. Рекомендовано Министерством общего и профессионального образования Российской Федерации в качестве учебник
| Вид материала | Учебник |
- Е. Л. Григоренко психогенетика под редакцией И. В. Равич-Щербо Рекомендовано Министерством, 27103.82kb.
- Г. В. Плеханова И. Н. Смирнов, В. Ф. Титов философия издание 2-е, исправленное и дополненное, 4810.28kb.
- К. Э. Фабри Основы зоопсихологии 3-е издание Рекомендовано Министерством общего и профессионального, 5154.41kb.
- Е. А. Климов введение в психологию труда рекомендовано Министерством общего и профессионального, 4594.17kb.
- Н. Ф. Самсонова Рекомендовано Министерством общего и профессионального образования, 6152.94kb.
- Ю. Г. Волков И. В. Мостовая социология под редакцией проф. В. И. Добренькова Рекомендовано, 6915.59kb.
- Е. Ф. Жукова Рекомендовано Министерством общего и профессионального образования Российской, 6286.83kb.
- О. А. Кривцун эстетика Рекомендовано Министерством общего и профессионального образования, 6381.8kb.
- В. И. Рудой классическая буддийская философия рекомендовано Министерством, общего, 6771.74kb.
- В. И. Ильинича Рекомендовано Министерством общего и профессионального Образования Российской, 6751.75kb.
5.2.Особенности реализации полиморфизма
В Delphi Pascal реализованы более сложные механизмы переопределения методов. Прежде всего в нем различают: виртуальные методы, динамические методы и абстрактные методы. Кроме того, в последних версиях языка реализована параметрическая перегрузка как обычных процедур и функций, так и методов. Использование соответствующих средств позволяет создавать существенно более мощные классы.
^ Виртуальные методы объектной модели, используемой Delphi, практически ничем не отличаются от тех, которые определялись в Borland Pascal 7.0. Для них также реализуется механизм позднего связывания, обеспечивая возможность построения виртуальных объектов. Не изменилась и сущность реализации механизма позднего связывания через ТВМ. Изменения коснулись лишь описания виртуальных методов. Теперь только самый первый виртуальный метод в иерархии описывается virtual, все же методы, перекрывающие этот метод, описываются со спецификатором override. Если же по ошибке какой-нибудь из этих методов описать virtual, то будет создано новое семейство виртуальных полиморфных методов, родоначальником которого является метод, описанный virtual по ошибке.
Примечание. Вызов конструктора выполняется следующим образом. Вначале он вызывается как метод класса и организует размещение в памяти нового объекта, а затем вызывается уже как обычный метод. Поэтому конструктор может объявляться виртуальным. Виртуальный конструктор позволяет создавать объекты различных типов, устанавливаемых во время выполнения программы.
^ Динамические методы. Динамическими в Delphi называются полиморфные виртуальные методы, доступ к которым выполняется не через ТВМ, а через специальную таблицу динамических методов (ТДМ). Такие методы описываются, соответственно, dimamic - при объявлении и override - при переопределении.
В отличие от ТВМ, которая хранит адреса всех виртуальных методов данного класса, ТДМ хранит только адреса виртуальных методов, определенных в данном классе (рис. 5.5). Если осуществляется вызов динамического метода, определенного в предках данного класса, то его адрес отыскивается в организованных в списковую структуру описаниях классов иерархии (ТВМ - раздел 5.6). Естественно, поиск такого метода займет больше времени по сравнению с виртуальными методами. Однако ТДМ занимает меньше места, так как не хранит всех предшествующих ссылок.
Рис. 5.72. Виртуальные и динамические методы
Из вышесказанного следует, что использовать динамическую реализацию полиморфных виртуальных методов имеет смысл лишь в тех случаях, когда класс имеет сотни потомков, а описываемый метод вызывается крайне редко, или, если метод переопределяется в каждом потомке. Во всех остальных случаях лучше использовать обычную реализацию (virtual).
^ Абстрактные методы. Абстрактные методы используются при объявлении методов, реализация которых откладывается. Такие методы в классе описываются служебным словом abstract и обязательно переопределяются в потомках класса.
Класс, в состав которого входят методы с отложенной реализацией, называется абстрактным. Создавать (конструировать) объекты абстрактных классов запрещается.
^ Пример 5.72. Использование абстрактных методов (графический редактор «Окружности и квадраты»)
Попробуем изменить пример предыдущего раздела так, чтобы можно было рисовать не только окружности, но и, например, квадраты.
Диаграмма объектов такого приложения изображена на рис. 5.6.
Рис. 5.73. Объектная декомпозиция приложения «Окружности и квадраты»
Естественно, теперь интерфейс должен обеспечивать возможность выбора фигуры. С этой цель добавим в форму компонент TRadioGroup - группу «радиокнопок» (рис. 5.7).
Рис. 5.74. Вид главного окна приложения «Окружности и квадраты»
Соответственно при обработке события С2 (рис.5.3) необходимо учитывать тип выбранной фигуры.
Класс TMainForm будет иметь ту же структуру, что и в предыдущем примере, но в него будет добавлено поле RadioGroup типа TRadioButton.
Класс TMySquare может быть построен несколькими способами.
1. Класс TMySquare можно наследовать от TObject, так же как был получен классTMyCircul. В этом случае нам придется повторить программирование всех методов данного класса, что явно не целесообразно.
2. Класс TMySquare можно наследовать от TMyCircul (рис.5.8a). Тогда мы можем наследовать от TMyCircul методы Create, Clear, ReColor, ReSize, определяющие общие элементы поведения. Метод Draw необходимо объявить виртуальным, так как он вызывается из наследуемых методов и переопределен в классе-потомке. Метод Draw класса TMySquare должен быть объявлен переопределенным - override. Данный вариант наследования принципиально применимый в конкретном случае является не универсальным (и, в общем, не логичным: как можно «наследовать» от круга квадрат?).
3. С учетом существования двух типов объектов со сходным поведением можно создать абстрактный класс TFigure, инкапсулирующий требуемый тип поведения фигур (рис. 5.8б). В этом классе нужно объявить метод Draw виртуальным (virtual) и абстрактным (abstract) и определить методы Create, Clear, ReColor, ReSize через метод Draw. Теперь мы можем наследовать от этого абстрактного класса классы, рисующие любые фигуры. Эти классы должны будут переопределять абстрактный метод Draw класса TMyFigure.
Рис. 5.75. Два варианта иерархии классов
Представленный ниже текст модуля Figures включает описание иерархии классов в соответствии c рис. 5.8б.
^ Unit Figure;
Interface
Uses extctrls,Graphics;
Type TMyFigure=class
private x,y,r:Word; Color:TColor; Image:TImage;
procedure Clear;
public
Constructor Сreate(aImage:TImage;ax,ay,ar:Word;aColor:TColor);
Procedure Draw; virtual; abstract; {абстрактная процедура}
Procedure ReSize(ar:Word);
Procedure ReColor(acolor:TColor);
end;
TMyCircul=class(TMyFigure) {класс Окружность}
public Procedure Draw; override; {рисование окружности}
end;
TMySquare=class(TMyFigure) {класс Квадрат}
public Procedure Draw; override; {рисование квадрата}
end;
Implementation
Constructor TMyFigure.Create;
Begin
inherited Create;
Image:=aImage; x:=ax; y:=ay; r:=ar; Color:=aColor;
End;
Procedure TMyFigure.Clear;
Var TempColor:TColor;
Begin TempColor:=Color;
Color:=Image.Canvas.Brush.Color;
Draw; {нарисовать фигуру цветом фона - стереть}
Color:=TempColor;
End;
Procedure TMyFigure.Resize;
Begin Clear; r:=ar; Draw; End;
Procedure TMyFigure.Recolor;
Begin Clear; Color:=aColor; Draw; End;
Procedure TMyCircul.Draw;
Begin Image.Canvas.Pen.Color:=Color;
Image.Canvas.Ellipse(x-r,y-r,x+r,y+r);
End;
Procedure TMySquare.Draw;
Begin Image.Canvas.Pen.Color:=Color;
Image.Canvas.Rectangle(x-r,y-r,x+r,y+r);
End;
End.
Пример демонстрирует, что использование абстрактных классов позволяет разрабатывать более универсальные и логически обоснованные иерархии.
Примечание. При создании аналогичных иерархий средствами Borland Pascal 7.0 приходилось использовать «пустые» методы, включающие только операторные скобки begin end. При этом компилятор не мог контролировать создание объектов абстрактных классов, предоставляя разработчику самостоятельно отыскивать ошибки данного вида.
^ Перегрузка методов. Начиная с версии 4, в Delphi Pascal появилась возможность перегрузки процедур и функций:
function Divide(X, Y: Real): Real; overload; {вариант 1}
begin Result := X/Y; end;
function Divide(X, Y: Integer): Integer; overload; {вариант 2}
begin Result := X div Y; end;
Какой конкретно вариант перегруженных процедур и функций вызван, определяется по типам фактических параметров:
k:=Divide(2.5, 7.3); {вызывается вариант 1}
k:=Divide(6,3); {вызывается вариант 2}
Перегружать можно не только простые процедуры и функции, но и методы. ^ Перегруженный метод не перекрывается как переопределенный, а остается доступным, как любой другой метод базового класса.
Для описания перегруженных методов используется служебное слово overload. Нужный аспект метода при его перегрузке также определяется по совпадению типов фактических параметров:
type
T1 = class(TObject)
public
procedure Test(I: Integer); overload;
end;
T2 = class(T1)
public
procedure Test(S: string); overload;
end;
…
Var SomeObject:T2;
…
SomeObject := T2.Create;
SomeObject.Test('Hello!'); {параметр строка - вызвается метод Test класса Т2}
SomeObject.Test(7); {параметр целое число - вызывается метод Test класса Т1}
В отличие от перегруженных методов С++ перегруженные методы Delphi Pascal не могут объявляться внутри одного класса:
^ Type
TSomeClass = class
public
function Func(P: Integer): Integer;
function Func(P: Boolean): Integer { ошибка!}
...
Если перегружается виртуальный метод, то компилятор выдает предупреждение о перекрытии доступа к этому методу. Для того, чтобы сообщить компилятору, что некоторый метод действительно должен перекрыть витруальный метод, используется служебное слово reintroduce.
Рассмотрим различные варианты переопределения виртуальных методов:
^ Type
T1 = class(TObject)
public procedure Act1; virtual;
procedure Act2; virtual;
procedure Act3; virtual;
procedure Act4; virtual;
procedure Act5; virtual;
end;
T2 = class(T1)
public
procedure Act1;override; {определение нового аспекта виртуального полиморфного метода}
procedure Act2;virtual; {определяется новый полиморфный метод – компилятор выдает предупреждение о возможной ошибке, так как при этом доступ к ранее описанному полиморфному методу перекрывается}
procedure Act3;reintroduce;virtual; {определяется новый полиморфный метод – компилятор предупреждения не выдает, так как пресечение доступа документировано}
procedure Act4; {переопределение виртуального метода простым – компилятор выдает предупреждение о возможной ошибке, так как при этом доступ к виртуальному методу перекрывается}
procedure Act4; reintroduce; {переопиределение виртуального метода простым – компилятор предупреждения не выдает, так как пресечение доступа документировано}
end;
var SomeObject1: T1;
begin
SomeObject1 := T2.Create; {указатель на базовый класс содержит адрес объекта производного класса}
SomeObject1.Act1; {позднее связывание – вызывается метод класса T2}
SomeObject1.Act2; {раннее связывание – вызывается метод класса T1}
SomeObject1.Act3; {раннее связывание – вызывается метод класса T1}
SomeObject1.Act4; {раннее связывание – вызывается метод класса T1}
SomeObject1.Act5; {раннее связывание – вызывается метод класса T1}
end;
Соответственно, описание классов, использующих перегрузку виртуальных методов, должно выполняться по следующему образцу:
type
T1 = class(TObject)
public
procedure Test(I: Integer); overload; virtual;
end;
T2 = class(T1)
public
procedure Test(S: string); reintroduce; overload;
end;
При перегрузке как обычных процедур и функций, так и методов, необходимо очень осторожно обращаться с параметрами, принимаемыми по умолчанию (которые также введены начиная с версии 4 Delphi):
procedure Confused(I: Integer); overload;
Begin… End;
procedure Confused (I: Integer; J: Integer = 0); overload;
Begin… End;
...
Confused(X); {ошибка компиляции, не определен вариант перегруженной процедуры}
Аналогичная ситуация при перегрузке методов не приводит к появлению сообщения об ошибке, просто один из перегруженных методов становится не доступным (в примере ниже не доступен перегруженный метод базового класса):
^ Type
T1 = class(TObject)
public
procedure Test(I: Integer); overload; virtual;
end;
T2 = class(T1)
public
procedureTest (I:Integer;S:string=’aaa’); reintroduce; overload;
end;
…
SomeObject := T2.Create;
SomeObject.Test(5,'Hello!'); {параметры целое число и строка - вызвается метод Test класса Т2}
SomeObject.Test(7); {параметр целое число - вызывается метод Test класса Т2 с параметром по умолчанию}
Перегрузить можно любой метод, в том числе и конструктор:
^ Type T1=class
public I:integer;
Constructor Create;overload;
end;
T2=class(T1)
public
Constructor Create(aI:Integer);overload;
end;
Constructor T1.Create;
Begin
inherited Create;
I:=10;
End;
Constructor T2.Create(aI:Integer);
Begin
inherited Create;
I:=aI;
End;
...
Var SomeObject:T2;
...
SomeObject:=T2.Create; {вызывается конструктор базового класса – в поле I записано 10}
SomeObject:=T2.Create(5); {вызывается конструктор производного класса – в поле I записано 5}